Return to DDW.m CVS log

Up to [Coherent Logic Development] / freem_fileman

Annotation of freem_fileman/DDW.m, revision 1.1.1.1

1.1       snw         1: DDW    ;SFISC/PD KELTZ-SCREEN EDITOR MAIN ROUTINE ;06:12 PM  13 Dec 1994
                      2:        ;;21.0;VA FileMan;;Dec 28, 1994
                      3:        ;Per VHA Directive 10-93-142, this routine should not be modified.
                      4: MAIN   N DX,DY,IOTM,IOBM
                      5:        I '$D(DIQUIET) N DIQUIET S DIQUIET=1
                      6:        I '$D(DIFM) N DIFM S DIFM=1 D INIZE^DIEFU
                      7:        ;
                      8:        D INIT I $G(DDWERR) K DDWERR Q
                      9:        D ^DDWT1,END
                     10:        Q
                     11:        ;
                     12: EDIT(DIC,DDWFLG,DIWETXT,DIWESUB,DDWRW,DDWC,DDWTM,DDWBM,DDWLMAR,DDWRMAR)        ;
                     13:        N DWHD,DWLC
                     14:        G MAIN
                     15:        ;
                     16: MSG(DDWX)      ;Write message
                     17:        S DY=$G(DDWBM,IOSL)-1,DX=0 X IOXY
                     18:        W $P(DDGLCLR,DDGLDEL)_$G(DDWX)
                     19:        I $G(DDWX)="",$D(DDWMARK) D IND^DDW7(1)
                     20:        Q
                     21:        ;
                     22: INIT   ;Setup, initialize variables
                     23:        N X,DDWI
                     24:        D INIT^DDGLIB0() G:$G(DIERR) ERR
                     25:        I $P(DDGLED,DDGLDEL,2)_$P(DDGLED,DDGLDEL,3)_$P(DDGLED,DDGLDEL,4)="" D TRMERR^DDGLIB0("Set Top and Bottom Margins, Delete Line, and Insert Line") G ERR
                     26:        ;
                     27:        G:'$D(DIC) FERR
                     28:        S DDWDIC=$$CREF^DILF(DIC) G:'$D(@DDWDIC) FERR
                     29:        S X="S X="_DDWDIC D ^DIM G:'$D(X) FERR
                     30:        S DIC=$$OREF^DILF(DDWDIC)
                     31:        ;
                     32:        S IOTM=$G(DDWTM,1)+2,IOBM=$G(DDWBM,IOSL)-3
                     33:        I IOBM-IOTM<3 D BLD^DIALOG(202,"Top and/or Bottom Margin") G ERR
                     34:        ;
                     35:        S:'$G(DDWLMAR) DDWLMAR=1 S:'$G(DDWRMAR) DDWRMAR=74
                     36:        I DDWRMAR'>DDWLMAR!(DDWLMAR>231)!(DDWRMAR>245) D BLD^DIALOG(202,"Left and/or Right Margin") G ERR
                     37:        ;
                     38:        D:$D(DDW("IN"))[0 GETKEY^DDWK
                     39:        ;
                     40:        D CLR
                     41:        W:$P(DDGLED,DDGLDEL,2)]"" @$P(DDGLED,DDGLDEL,2)
                     42:        X DDGLZOSF("EOFF"),DDGLZOSF("TRMON")
                     43:        ;
                     44:        K DDWL,^TMP("DDW",$J),^TMP("DDW1",$J)
                     45:        S (DDWA,DDWSTB,DDWSTAT,DDWREP)=0,DDWBF="0010"
                     46:        ;
                     47:        S DDWRAP=$G(DDWFLG)'["M"
                     48:        I 'DDWRAP D
                     49:        . S DDWLMAR(1)=DDWLMAR,DDWLMAR=1
                     50:        . S DDWRMAR(1)=DDWRMAR,DDWRMAR=245
                     51:        ;
                     52:        I '$G(DDWRW),$G(DDWRW)'="B" S DDWRW=1
                     53:        I '$G(DDWC),$G(DDWC)'="E" S DDWC=1
                     54:        ;
                     55:        S DDWTO=DTIME
                     56:        S DDWOFS="0^20^^1",$P(DDWOFS,U,3)=IOM-$P(DDWOFS,U,2)
                     57:        S DDWMR=IOBM-IOTM+1
                     58:        ;
                     59:        S DDWRUL=$TR($J("",255)," ","=")
                     60:        F DDWI=1:1:31 S $E(DDWRUL,DDWI*8)="T"
                     61:        Q
                     62:        ;
                     63: RESET  ;Reset terminal and cleanup
                     64:        D INIT^DDGLIB0() D:$G(DIERR) MSG^DIALOG("BW")
                     65:        W $P($G(DDGLVID),DDGLDEL,10)
                     66:        ;
                     67: END    ;Cleanup
                     68:        I $P(DDGLED,DDGLDEL,2)]"" D
                     69:        . S IOTM=1,IOBM=$S($D(IOSL)#2:IOSL,1:24) W @$P(DDGLED,DDGLDEL,2)
                     70:        D CLR
                     71:        ;
                     72:        K DDW,DDWA,DDWBF,DDWC,DDWCHG,DDWCNT,DDWDIC,DDWFIN,DDWFIND,DDWL
                     73:        K DDWMARK,DDWMR,DDWN,DDWOFS,DDWQ,DDWRAP,DDWREP
                     74:        K DDWRUL,DDWRW,DDWSTAT,DDWSTB,DDWTC,DDWTO
                     75:        K ^TMP("DDW",$J),^TMP("DDW1",$J),^TMP("DDWH",$J)
                     76:        I $$ROUEXIST^DILIBF("XPDUTL"),$$VERSION^XPDUTL("XU")>7.1
                     77:        E  K ^TMP("DDWB",$J)
                     78:        ;
                     79:        ;D:'$D(DIWE) X^DIWE
                     80:        D:$D(DDS)[0 KILL^DDGLIB0($G(DDWFLG))
                     81:        Q
                     82:        ;
                     83: CLR    ;Clear screen
                     84:        I $G(DDWTM,1)=1,$G(DDWBM,IOSL)=IOSL W $P(DDGLCLR,DDGLDEL,2)
                     85:        E  D
                     86:        . S DX=0
                     87:        . F DY=$G(DDWTM,1)-1:1:$G(DDWBM,IOSL)-1 X IOXY W $P(DDGLCLR,DDGLDEL)
                     88:        Q
                     89:        ;
                     90: FERR   ;File input parameter error
                     91:        D BLD^DIALOG(202,"File")
                     92:        D ERR
                     93:        Q
                     94:        ;
                     95: ERR    ;Error during setup
                     96:        W $C(7),! D MSG^DIALOG("BW") W !
                     97:        D KILL^DDGLIB0()
                     98:        S DDWERR=1
                     99:        Q