Return to DIKZ0.m CVS log

Up to [Coherent Logic Development] / freem_fileman

Initial revision

DIKZ0	;SFISC/XAK-XREF COMPILER ;12/12/94  14:54
	;;21.0;VA FileMan;;Dec 28, 1994
	;Per VHA Directive 10-93-142, this routine should not be modified.
	S DIK0=" I X'=""""" D DD^DIK,A,SD Q:DIKZQ
RET	I $D(DK1) S A=A+1,DIKA=1,DH=0 F  S DH=$O(DK1(DH)) Q:DH'>0  D E^DIK
	S:DH="" DH=-1 I $D(DK1) K DK1 D SD Q:DIKZQ  G RET
	Q
SD	F DH=DH(1):0 S DH=$O(DU(DH)) Q:DH'>0  S:$D(^DD(DH,"SB")) DK1(DH)="" D DD1^DIK,0 Q:DIKZQ  S:$D(^DD(DH,"IX")) DIK(X,DH)="A1^"_DNM_DRN K:'$D(^("IX")) DIK(X,DH) K DU(DH)
	Q
0	;
	D SV^DIKZ Q:DIKZQ  S DIK1=""
	I $D(DIKA) S DIK1=" S DA("_A_")=DA"_$S(A=1:"",1:"("_(A-1)_")")
	F DIKL2=A-1:-1:1 S DIK1=DIK1_" S DA("_DIKL2_")=0"
	S ^UTILITY($J,DIKR+1)=DIK1_" S DA=0",DIKR=DIKR+2,^(DIKR)="A1 ;"
	K DIKA D ^DIKZ2 S DIKLW=1
	S DIKR=DIKR+1,DIK=DIK2_DIK8(DH),^UTILITY($J,DIKR)=A_" ;",DIKR=DIKR+1
A	;
	F DIKQ=0:0 S DIKQ=$O(^UTILITY("DIK",$J,DH,DIKQ)) Q:DIKQ'>0  S %=^(DIKQ) S:+%'=% %=""""_%_"""" D PUT
	K ^UTILITY("DIK",$J),DIK6
	Q
PUT	I '$D(DIK6(%)) S ^UTILITY($J,DIKR)=" S DIKZ("_%_")=$G("_DIK_"DA,"_%_"))",DIK6(%)=""
	S DIKR=DIKR+1,(DIK6,^UTILITY($J,DIKR))=" "_$P(^UTILITY("DIK",$J,DH,DIKQ,0),"^(X)")_"DIKZ("_%_")"_$P(^(0),"^(X)",2,9)
	F DIKC=0:0 S DIKC=$O(^UTILITY("DIK",$J,DH,DIKQ,DIKC)) Q:DIKC'>0  S %=^(DIKC) S:$O(^(0))'=DIKC DIKR=DIKR+1,^UTILITY($J,DIKR)=DIK6 D CRF
	S DIKR=DIKR+1 Q
	;
CRF	S DIKR=DIKR+1
	I %["Q:"!(%[" Q") S ^UTILITY($J,DIKR)=DIK0_" X ^DD("_DH_","_DIKQ_",1,"_DIKC_","_X_")" Q
	I %["D RCR" S ^UTILITY($J,DIKR)=DIK0_" D",DIKR=DIKR+2,^(DIKR-1)=" .N DIK,DIV,DIU,DIN",^UTILITY($J,DIKR)=" ."_^UTILITY("DIK",$J,DH,DIKQ,DIKC,0) Q
	I %["S XMB=" S ^UTILITY($J,DIKR)=DIK0_",$D(DIK(0)),DIK(0)[""B"" S DIKZR="_DIKC_",DIKZZ="_DIKQ_" D BUL^"_DNM,DIKR=DIKR+1,^UTILITY($J,DIKR)=DIK0_",'$D(DIKOZ) "_$S($L(%)<225:%,1:"X ^DD("_DH_","_DIKQ_",1,"_DIKC_","_X_")") Q
	S ^UTILITY($J,DIKR)=DIK0_" "_$S(%[" AUDIT":"S DH="_DH_",DV="_DIKQ_",DU="_A_" ",1:"")_%_$S(%[" AUDIT":"^DIK1",1:"")
	Q