Return to DIQGDDU.m CVS log

Up to [Coherent Logic Development] / freem_fileman

Initial commit

DIQGDDU	;SFISC/DCL-DATA DICTIONARY UTILITIES ;10:55 AM  1 Aug 1994;
	;;21.0;VA FileMan;;Dec 28, 1994
	;Per VHA Directive 10-93-142, this routine should not be modified.
	Q
FL(DIQGFILE,DIQGFLD)	;RETURNS FIELD LENGTH
	;FILENUMBER,FIELDNUMBER
	;Short version of DIOS1
	I $G(DIQGFILE)'>0 D ERR202("FILE NUMBER") Q ""
	I $G(DIQGFLD)'>0 D ERR202("FIELD NUMBER") Q ""
	I '$D(^DD(DIQGFILE,DIQGFLD,0)) D ERR1700("DD FOR FILE#"_DIQGFILE_", FIELD#"_DIQGFLD_" DOES NOT EXIST") Q ""
	N DN,W
X	S DN=$P(^(0),"^",2),W=+$P(DN,"J",2) G DJ:W I $P(DN,"P",2)!(DN) G X:$D(^DD($S(DN:DN,1:+$P(DN,"P",2)),.01,0)),DJ
	I DN["C",DN'["J" S W=30
	I DN'["F" S W=13 G DJ
	S W=+$P(^(0),"$L(X)>",2) S:'W W=30
DJ	Q W
	;
ERR202(DIQGERR)	;Error processing
	N P S P(1)=DIQGERR
	D BLD^DIALOG(202,.P)
	Q
ERR1700(DIQGERR)	;Error processing
	N P S P(1)=DIQGERR
	D BLD^DIALOG(1700,.P)
	Q
	;
RIF(DA,DR,DIQGETA)	;FUNCTION CALL FOR RI
RI	;REQUIRED IDENTIFIERS - CALLED BY EN3^DIQGDD
	;DA=FILENR,DR="REQUIRED IDENTIFIERS",DIQGETA=TARGET_ARRAY
	N DIQGRIA,DIQGRI,DIQGR
	D REQIDS^DICU(DA,"DIQGRIA")
	S DIQGRIA="",DIQGRI=0
	F  S DIQGRIA=$O(DIQGRIA(DR,DIQGRIA)) Q:DIQGRIA=""  D
	.S DIQGRI=DIQGRI+1,@DIQGETA@(DR,DIQGRI,"FIELD")=DIQGRIA
	.Q
	Q $S(DIQGRI:$NA(@DIQGETA@(DR)),1:"")