Return to DDSRSEL.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

DDSRSEL	;SFISC/MKO-RECORD SELECTION ;12:45 PM  11 Sep 1994
	;;21.0;VA FileMan;;Dec 28, 1994
	;Per VHA Directive 10-93-142, this routine should not be modified.
	;
PG	;Called from:
	;  DDS01 when user presses SELECT
	;  FIRSTPG^DDS0 if no DA was passed in.
	;
	;Returns (if there is a record selection page and we're not in
	;a multiple)
	; DDSPG  = Record selection page #
	; DDACT  = "NP"
	; DDSSEL = 1 (undefined if no record selection page)
	;
	N P,P1 K DDSSEL
	I $D(DDSSC),$P(DDSSC(DDSSC),U,4) Q
	;
	S P="",P1=$P($G(^DIST(.403,+DDS,21)),U)
	I P1]"" D
	. S P=$O(^DIST(.403,+DDS,40,"B",P1,""))
	. I P]"",$D(^DIST(.403,+DDS,40,P,0))[0 S P=""
	;
	I P]"" D
	. I DDO,$G(DDSDN)=1 D
	.. D ERR3^DDS3
	. E  S DDSPG=P,DDACT="NP",DDSSEL=1
	Q
	;
GDA	;Called from DDS
	;After a record selection page is closed get the DA from
	;the first field on the page.
	N DDSANS,DDSDASV,DDSREC,Y
	S DDSDASV=DA,DDSANS=""
	S DDSREC=$$GET^DDSVALF(1,1,$P(^DIST(.403,+DDS,21),U))
	;
	I DDSREC]"",DA'=DDSREC D
	. S DA=DDSREC
	. D REC^DDS0(DDP,.DA)
	. I $G(DIERR) D ERR^DDSMSG H 2 S DA=DDSDASV Q
	. I DDSDASV D
	.. S DDSANS=$$ASKSAVE Q:DDSANS=U  D:DDSANS="S" S^DDS3
	.. D CLRDAT,UNLOCK
	. I DDSANS=U S DA=DDSDASV Q
	. I DDSSC=1 D FRSTPG^DDS0(DDS,.DA,$G(DDSPAGE)) S DDACT="N"
	K DDSSEL
	Q
	;
ASKSAVE()	;
	;Ask user whether to save the previous record
	;Returns U:abort, 1:save, 2:discard
	N X,Y D:DDM CLRMSG^DDS
	S DDM=1
	;
	K DIR S DIR(0)="SM^S:SAVE;D:DISCARD;R:RETURN"
	S DIR("A",1)="  NOTE:  YOU MUST SAVE OR DISCARD ALL EDITS TO THE"
	S DIR("A",2)="         PREVIOUS RECORD BEFORE EDITING THE NEXT RECORD."
	S DIR("A")="Save, Discard, or Return to previous record (S/D/R)"
	S DIR("B")="SAVE"
	;
	S DIR("?",1)="Enter 'S' to save or 'D' to discard."
	S DIR("?")="Enter 'R' or '^' to return to previous record."
	;
	S DIR0=IOSL-1_U_($L(DIR("A"))+1)_"^7^"_(IOSL-3)_"^0"
	D ^DIR
	I $D(DIRUT) S Y=U
	E  S:X="SAVE" Y="S",Y(0)="SAVE"
	K DIR,DIROUT,DIRUT,DTOUT,DUOUT
	Q Y
	;
CLRDAT	;Clear all data values from @DDSREFT
	N F,P
	S P=0 F  S P=$O(@DDSREFT@(P)) Q:'P  K @DDSREFT@(P)
	S F="F" F  S F=$O(@DDSREFT@(F)) Q:$E(F)'="F"  K @DDSREFT@(F)
	Q
	;
UNLOCK	;Unlock all records locked
	Q:'$D(^TMP("DDS",$J,"LOCK"))
	N I S I=""
	F  S I=$O(^TMP("DDS",$J,"LOCK",I)) Q:I=""  D
	. I I'=(DIE_DA_")") L -@I K ^TMP("DDS",$J,"LOCK",I)
	Q