Return to DDWH.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

DDWH	;SFISC/MKO-SCREEN EDITOR HELP ;08:38 AM  23 Nov 1994
	;;21.0;VA FileMan;;Dec 28, 1994
	;Per VHA Directive 10-93-142, this routine should not be modified.
HLP	;
	N DX,DY,DDWI
	;
	D HLP^DDGLIBH(9211,9214,"DDWH",IOBM+2)
	D BOX^DDW1
	;
	S DY=IOTM-1,DX=0 X IOXY
	F DDWI=1:1:DDWMR W $P(DDGLCLR,DDGLDEL)_$$LINE(DDWI,$G(DDWMARK))_$S(DDWI<DDWMR:$C(13,10),1:"")
	;
	D:$D(DDWMARK) IND^DDW7(1)
	Q
	;
LINE(DDWI,DDWMARK)	;
	N DDWX
	S DDWX=$E(DDWL(DDWI),1+DDWOFS,IOM+DDWOFS)
	Q:$G(DDWMARK)="" DDWX
	;
	N DDWR1,DDWC1,DDWR2,DDWC2
	S DDWR1=$P(DDWMARK,U,1),DDWC1=$P(DDWMARK,U,2)
	S DDWR2=$P(DDWMARK,U,3),DDWC2=$P(DDWMARK,U,4)
	;
	I DDWI'<(DDWR1-DDWA),DDWI'>(DDWR2-DDWA) D
	. N DDWX1,DDWX2
	. S DDWX1=$S(DDWI=(DDWR1-DDWA):DDWC1,1:1)
	. S DDWX2=$S(DDWI=(DDWR2-DDWA):DDWC2,1:999)
	. S DDWX=$E(DDWL(DDWI),1+DDWOFS,DDWX1-1)_$P(DDGLVID,DDGLDEL,6)_$E(DDWL(DDWI),$$MAX(DDWX1,1+DDWOFS),$$MIN(DDWX2,IOM+DDWOFS))_$P(DDGLVID,DDGLDEL,10)_$E(DDWL(DDWI),$$MAX(DDWX2+1,1+DDWOFS),IOM+DDWOFS)
	Q DDWX
	;
MIN(X,Y)	;
	Q $S(X<Y:X,1:Y)
	;
MAX(X,Y)	;
	Q $S(X>Y:X,1:Y)