Return to DINIT6.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

DINIT6	;SFISC/XAK-INITIALIZE VA FILEMAN ;9/1/94  11:17
	;;21.0;VA FileMan;;Dec 28, 1994
	;Per VHA Directive 10-93-142, this routine should not be modified.
	I $D(^DD("OS"))[0 D OS^DINIT
	W !!,"The following files have been installed:",!
	F X=0:0 S X=$O(^DIC(X)) Q:X>1.9999  Q:'X  W $E("   ",1,(3-$L($P(X,"."))))_X,?8,$P($G(^DIC(X,0)),U),! S ^DD(X,0,"VR")=VERSION
	S ^DD("VERSION")=VERSION,X=^DD("OS",^DD("OS"),0)
	S ^DD("SUB")=$P(X,U,3),^("ROU")=$P(X,U,4)
	D 1
	D ^DINITPST
E	W !,"INITIALIZATION COMPLETED IN "_($P($H,",",2)-DIT)_" SECONDS."
	D KL Q
	;
1	N DIT
	D KL,PKG,DIINIT
	Q
	;
KL	K %,%H,%X,%Y,DD,DH,DIC,DIK,DIT,DITZS,D,DA,VERSION,DU,F,I,J,P,X,Y,DIRUT,DTOUT,DUOUT
	Q
PKG	;
	I $D(^DIC(9.4,0))#2,($P(^DIC(9.4,0),U,1)'="PACKAGE") D  Q
	. W !!,"You have a file #9.4 that is not the 'Package' file."
	. W !,"Therefore, the Package file will not be initialized on your system."
	. W !,"You cannot use VA FileMan's package export utility, DIFROM."
	. Q
	I $$ROUEXIST^DILIBF("XPDUTL"),$$VERSION^XPDUTL("XU")>7.1 Q
	K ^DD(9.4,913.5,2),^DD(9.4,914.5,2),^DD(9.4,916.5,2),^DD(9.44,222.7,2),^DD(9.44,222.9,2),^DD(9.44,1909)
	W !!,"Your Package file will now be updated.",!!
	D EN^DIPKINIT
	Q
DIINIT	;
	I $P($G(^DIC(19,0)),U,1)="OPTION",$P($G(^DIC(19.1,0)),U,1)="SECURITY KEY" D
	. W !!,"Options and security keys will now be added to your system.",!!
	. D EN^DIINIT
	. Q
	;Put PACKAGE pointer into FM DIALOG entries, re-index file
	W !!,"Re-indexing VA FileMan entries in the DIALOG file."
	N DIPKG,DIREC S DIPKG=$O(^DIC(9.4,"C","DI",0))
	F DIREC=0:0 S DIREC=$O(^DI(.84,DIREC)) Q:'DIREC!(DIREC>10000)  D
	. S $P(^DI(.84,DIREC,0),U,4)=DIPKG
	. S DIK="^DI(.84,",DA=DIREC D IX1^DIK
	. Q
	Q