Return to m4_ax_append_flag.m4 CVS log

Up to [Coherent Logic Development] / freem / m4

Only use -Wno-format-truncation et al when the compiler supports them

    1: # ===========================================================================
    2: #      https://www.gnu.org/software/autoconf-archive/ax_append_flag.html
    3: # ===========================================================================
    4: #
    5: # SYNOPSIS
    6: #
    7: #   AX_APPEND_FLAG(FLAG, [FLAGS-VARIABLE])
    8: #
    9: # DESCRIPTION
   10: #
   11: #   FLAG is appended to the FLAGS-VARIABLE shell variable, with a space
   12: #   added in between.
   13: #
   14: #   If FLAGS-VARIABLE is not specified, the current language's flags (e.g.
   15: #   CFLAGS) is used.  FLAGS-VARIABLE is not changed if it already contains
   16: #   FLAG.  If FLAGS-VARIABLE is unset in the shell, it is set to exactly
   17: #   FLAG.
   18: #
   19: #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION.
   20: #
   21: # LICENSE
   22: #
   23: #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
   24: #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
   25: #
   26: #   Copying and distribution of this file, with or without modification, are
   27: #   permitted in any medium without royalty provided the copyright notice
   28: #   and this notice are preserved.  This file is offered as-is, without any
   29: #   warranty.
   30: 
   31: #serial 8
   32: 
   33: AC_DEFUN([AX_APPEND_FLAG],
   34: [dnl
   35: AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_SET_IF
   36: AS_VAR_PUSHDEF([FLAGS], [m4_default($2,_AC_LANG_PREFIX[FLAGS])])
   37: AS_VAR_SET_IF(FLAGS,[
   38:   AS_CASE([" AS_VAR_GET(FLAGS) "],
   39:     [*" $1 "*], [AC_RUN_LOG([: FLAGS already contains $1])],
   40:     [
   41:      AS_VAR_APPEND(FLAGS,[" $1"])
   42:      AC_RUN_LOG([: FLAGS="$FLAGS"])
   43:     ])
   44:   ],
   45:   [
   46:   AS_VAR_SET(FLAGS,[$1])
   47:   AC_RUN_LOG([: FLAGS="$FLAGS"])
   48:   ])
   49: AS_VAR_POPDEF([FLAGS])dnl
   50: ])dnl AX_APPEND_FLAG