Return to DDS3.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DDS3	;SFISC/MLH-COMMAND UTILS ;12:44 PM  11 Sep 1994
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: 	I Y(0)]"","ECNRS"[$E(Y(0)) D @$E(Y(0))
    5: 	Q
    6: 	;
    7: S	;Save the form
    8: 	D ^DDS4,R^DDSR
    9: 	D:$D(DDSBR)#2 BR^DDS2
   10: 	Q
   11: 	;
   12: R	;Repaint all pages on current screen
   13: 	;Called after wp, mults, and deletions
   14: 	G R^DDSR
   15: 	;
   16: E	;
   17: 	I DDSSC>1!'DDSCHG!$P(DDSSC(DDSSC),U,4) S DDACT="Q" Q
   18: 	S DDM=1
   19: 	K DIR S DIR(0)="YO"
   20: 	S DIR("A")=$$EZBLD^DIALOG(8075)
   21: 	D BLD^DIALOG(9037,"","","DIR(""?"")")
   22: 	S DIR0=IOSL-1_U_($L(DIR("A"))+1)_"^3^"_(IOSL-1)_"^0"
   23: 	D ^DIR
   24: 	K DIR,DUOUT,DIROUT,DIRUT
   25: 	;
   26: 	I Y=0!$D(DTOUT)!$D(DUOUT) D QT Q
   27: 	I Y="" S DDACT="N" Q
   28: 	I Y=1 D EX
   29: 	Q
   30: N	;
   31: 	S:DDSNP]"" DDSPG=DDSNP,DDACT="NP"
   32: 	Q
   33: C	;
   34: 	S DDACT="Q"
   35: 	Q
   36: 	;
   37: QT	;Exit, don't save
   38: 	G:DDSSC>1!$G(DDSSEL)!$P(DDSSC(DDSSC),U,4) ERR1
   39: 	I $G(DDSDN)=1,DDO G ERR3
   40: 	S DDACT="Q" Q:'DDSCHG
   41: 	D DEL^DDS6
   42: 	S DX=0,DY=IOSL-1 X IOXY
   43: 	W $P(DDGLCLR,DDGLDEL),$S($D(DTOUT):$$EZBLD^DIALOG(8076),1:"")_$$EZBLD^DIALOG(8077) H 1
   44: 	Q
   45: 	;
   46: EX	;Exit, save
   47: 	G:DDSSC>1!$G(DDSSEL)!$P(DDSSC(DDSSC),U,4) ERR1
   48: 	I $G(DDSDN)=1,DDO G ERR3
   49: 	S DDACT="Q"
   50: 	D ^DDS4 I 'Y S DDACT="N" D R
   51: 	Q
   52: CL	;Close
   53: 	I DDSSC'>1,'$G(DDSSEL),'$P(DDSSC(DDSSC),U,4) G ERR2
   54: 	I $G(DDSDN)=1,DDO G ERR3
   55: 	G E
   56: 	;
   57: TO	;Time-out
   58: 	I DDO,$G(DDSDN) S DDACT="N" G CURSOR^DDS01
   59: 	I DDO S DDSOSV=DDO,DDO=0
   60: 	E  D E
   61: 	Q
   62: 	;
   63: ERR1	;Print error message
   64: 	D MSG^DDSMSG("You must press <PF1>C to close this page.",1)
   65: 	S DDACT="N"
   66: 	Q
   67: 	;
   68: ERR2	;
   69: 	D MSG^DDSMSG("You must press <PF1>Q or <PF1>E to leave the form.",1)
   70: 	S DDACT="N"
   71: 	Q
   72: 	;
   73: ERR3	;
   74: 	D MSG^DDSMSG("Since navigation for the block is disabled, that key sequence is disabled.",1)
   75: 	S DDACT="N"
   76: 	Q
   77: 	;
   78: 	;#8075  Save changes before leaving form (Y/N)?
   79: 	;#8076  Time out.
   80: 	;#8077  Changes not saved!
   81: 	;#9037  Enter 'Y' to save before exiting...(3 lines)