Return to DDSIT.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DDSIT	;SFISC/MKO-INPUT TRANSFORMS ;09:07 AM  24 Oct 1994
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: 	;
    5: PFIELD	;Input transform for the PARENT FIELD field of the PAGE multiple
    6: 	;of the Form file.
    7: 	N DDSMF
    8: 	S DDSMF=$$GETFLD^DDSLIB($P(X,","),$P(X,",",2),$P(X,",",3),DA(1))
    9: 	G QUIT
   10: 	;
   11: PLINK	;Input transform for POINTER LINK field of the BLOCK multiple of
   12: 	;the PAGE MULTIPLE of the Form file.
   13: 	N DDP,DDSCD,DDSERR,DDS
   14: 	;
   15: 	S DDP=$P($G(^DIST(.403,DA(2),0)),U,8)
   16: 	I 'DDP D  G QUIT
   17: 	. N P
   18: 	. S P(1)="PRIMARY FILE",P(2)="FORM"
   19: 	. D BLD^DIALOG(3011,.P)
   20: 	;
   21: 	S DDS=DA(2)_U_$P(^DIST(.403,DA(2),0),U)
   22: 	D:X?1"FO(".E FO^DDSPTR(DDP,X,DA(2),DA(1))
   23: 	D:X'?1"FO(".E DD^DDSPTR(DDP,X,DA)
   24: 	G QUIT
   25: 	;
   26: CEXPR	;Input transform for COMPUTED EXPRESSION field
   27: 	N DDP,DDSX,DDSNEXP
   28: 	S DDP=$P($G(^DIST(.404,DA(1),0)),U,2)
   29: 	D PARSE^DDSCOMP(DDP,X,DA(1),.DDSNEXP) G:$G(DIERR) QUIT
   30: 	;
   31: 	S DDSX=X,X=DDSNEXP D ^DIM S:$D(X) X=DDSX
   32: 	Q
   33: 	;
   34: QUIT	;Check error and quit
   35: 	I $G(DIERR) N DDSERR D MSG^DIALOG("AB",.DDSERR),EN^DDIOL(.DDSERR) K X
   36: 	Q