Return to DDW7.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DDW7	;SFISC/MKO-MARK TEXT ;09:09 AM  21 Jun 1994
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: 	;
    5: MARK	;Mark the text
    6: 	I $D(DDWMARK) D
    7: 	. D BOUND
    8: 	E  D
    9: 	. S DDWMARK=DDWA+DDWRW_U_DDWC_U_(DDWA+DDWRW)_U_$$MAX(DDWC,$L(DDWN))
   10: 	. D PAINT(DDWMARK,1),IND(1)
   11: 	Q
   12: 	;
   13: BOUND	;Mark ending boundary, highlight selected text
   14: 	N DDWI,DDWX,DDWY
   15: 	;
   16: 	S DDWI=DDWA+DDWRW_U_DDWC
   17: 	S DDWX=$P(DDWMARK,U,1,2)
   18: 	S DDWY=$P(DDWMARK,U,3,4)
   19: 	;
   20: 	I $$ISLESS(DDWI,DDWX) D
   21: 	. D PAINT(DDWX_U_DDWY)
   22: 	. D PAINT(DDWI_U_DDWX,1)
   23: 	. S DDWMARK=DDWI_U_DDWX
   24: 	E  D
   25: 	. I $$ISLESS(DDWI,DDWY) D
   26: 	.. D PAINT(DDWI_U_DDWY),PAINT(DDWI_U_DDWI,1)
   27: 	. E  D PAINT(DDWY_U_DDWI,1)
   28: 	. S DDWMARK=DDWX_U_DDWI
   29: 	D CUP(DDWRW,DDWC-DDWOFS)
   30: 	Q
   31: 	;
   32: UNMARK	;Unmark the text
   33: 	D:$D(DDWMARK) PAINT(DDWMARK),IND()
   34: 	K DDWMARK
   35: 	Q
   36: 	;
   37: PAINT(DDWMARK,DDWREV)	;Paint selected text
   38: 	N DDWI,DDWR1,DDWC1,DDWR2,DDWC2
   39: 	S DDWR1=$P(DDWMARK,U,1),DDWC1=$P(DDWMARK,U,2)
   40: 	S DDWR2=$P(DDWMARK,U,3),DDWC2=$P(DDWMARK,U,4)
   41: 	;
   42: 	W:$G(DDWREV) $P(DDGLVID,DDGLDEL,6)
   43: 	F DDWI=$$MAX(DDWR1-DDWA,1):1:$$MIN(DDWR2-DDWA,DDWMR) D
   44: 	. D CUP(DDWI,$S(DDWI+DDWA=DDWR1:DDWC1-DDWOFS,1:1))
   45: 	. W $E(DDWL(DDWI),$S(DDWI+DDWA=DDWR1:DDWC1,1:1+DDWOFS),$$MIN($S(DDWI+DDWA=DDWR2:DDWC2,1:999),IOM+DDWOFS))
   46: 	W:$G(DDWREV) $P(DDGLVID,DDGLDEL,10)
   47: 	Q
   48: 	;
   49: IND(DDWX)	;Paint indicator
   50: 	S DY=$G(DDWBM,IOSL)-1,DX=IOM-7 X IOXY
   51: 	I $G(DDWX) D
   52: 	W $S($G(DDWX):$P(DDGLVID,DDGLDEL,6)_"Select"_$P(DDGLVID,DDGLDEL,10),1:$P(DDGLCLR,DDGLDEL))
   53: 	D CUP(DDWRW,DDWC-DDWOFS)
   54: 	Q
   55: 	;
   56: CUP(Y,X)	;
   57: 	S DY=IOTM+Y-2,DX=X-1 X IOXY
   58: 	Q
   59: 	;
   60: POS(R,C,F)	;Pos cursor based on char pos C
   61: 	N DDWX
   62: 	S:$G(C)="E" C=$L($G(DDWL(R)))+1
   63: 	S:$G(F)["N" DDWN=$G(DDWL(R))
   64: 	S:$G(F)["R" DDWRW=R,DDWC=C
   65: 	;
   66: 	S DDWX=C-DDWOFS
   67: 	I DDWX>IOM!(DDWX<1) D SHIFT^DDW3(C,.DDWOFS)
   68: 	S DY=IOTM+R-2,DX=C-DDWOFS-1 X IOXY
   69: 	Q
   70: 	;
   71: ISLESS(X,Y)	;Is coordinate X less than coordinate Y
   72: 	N R1,C1,R2,C2
   73: 	S R1=$P(X,U),C1=$P(X,U,2)
   74: 	S R2=$P(Y,U),C2=$P(Y,U,2)
   75: 	;
   76: 	Q:R1>R2 0
   77: 	Q:R1<R2 1
   78: 	Q:C1>C2 0
   79: 	Q 1
   80: 	;
   81: MIN(X,Y)	;
   82: 	Q $S(X<Y:X,1:Y)
   83: 	;
   84: MAX(X,Y)	;
   85: 	Q $S(X>Y:X,1:Y)