Return to DIFROM7.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DIFROM7	;SFISC/(SLC/STAFF)-SITE TRACKING INSTALL BULLETIN ;01:06 PM  23 Aug 1993
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: SETUP(ROUTINE,STATUS)	;
    5: 	K ^TMP($J) N LINE,LINE1,LINE2,NUM,OK,ROUTINIS,TXT
    6: 	D LOAD(ROUTINE,"^TMP($J,",0)
    7: 	I $P($P(^TMP($J,1,0),";")," ")'?1U1.3UN1"INIT" S STATUS="not changed" Q
    8: 	S ROUTINIS=$P(ROUTINE,"INIT")_"INIS"
    9: 	S (OK,LINE)=0 F  S LINE=$O(^TMP($J,LINE)) Q:LINE<0  S TXT=^(LINE,0) S:TXT[("PAC^"_ROUTINIS) OK=2 Q:OK=2  I TXT["=DIFROM G Q^DIFROM" S OK=1 Q
   10: 	I 'OK S STATUS="not installed" Q
   11: 	I OK=1 D
   12: 	.S ^TMP($J,LINE-.9,0)=" I DIFROM,$D(^%ZTSK) S X="""_ROUTINIS_""" X ^%ZOSF(""TEST"") D:$T PAC^"_ROUTINIS_"($T(IXF),.DIFROM)"
   13: 	.D SAVE(ROUTINE,"^TMP($J,",0)
   14: 	.S STATUS="site tracking installed"
   15: 	I OK=2 S STATUS="already installed"
   16: 	S LINE1=ROUTINIS_$P(^TMP($J,1,0),ROUTINE,2,99),LINE2=^TMP($J,2,0) K ^TMP($J)
   17: 	S ^TMP($J,1,0)=LINE1,^TMP($J,2,0)=LINE2
   18: 	F NUM=3:1 S LINE=$P($T(NMSPINIS+NUM),";",3,99) Q:LINE=""  D
   19: 	.I LINE["@@@@@@" S LINE=$P(LINE,"@@@@@@")_ROUTINIS_$P(LINE,"@@@@@@",2)
   20: 	.S ^TMP($J,NUM,0)=LINE
   21: 	D SAVE(ROUTINIS,"^TMP($J,",0)
   22: 	S STATUS=STATUS_" -- "_ROUTINIS_" saved"
   23: 	K ^TMP($J)
   24: 	Q
   25: LOAD(X,DIF,XCNP)	X ^%ZOSF("LOAD")
   26: 	Q
   27: SAVE(X,DIE,XCN)	X ^%ZOSF("SAVE")
   28: 	Q
   29: NMSPINIS	;;
   30: 	;;
   31: 	;;
   32: 	;;PAC(PKG,VER) ; called from package init (DIFROM7 created this routine)
   33: 	;; ; PKG = $T(IXF) of the INIT routine.
   34: 	;; ; VER is an array that is contained in DIFROM from the INIT routine
   35: 	;; ;
   36: 	;; N %,%I,%H,DATE,DIFROM,NOW,PACKAGE,RUN,SERVER,SITE,START,X,XMDUZ,XMSUB,XMTEXT,XMY,Y K ^TMP("@@@@@@",$J)
   37: 	;; ;
   38: 	;; ; Site tracking updates only occur if run in a VA production primary domain
   39: 	;; ; account.
   40: 	;; I $G(^XMB("NETNAME"))'[".VA.GOV" Q
   41: 	;; Q:'$D(^%ZOSF("UCI"))  Q:'$D(^%ZOSF("PROD"))
   42: 	;; X ^%ZOSF("UCI") I Y'=^%ZOSF("PROD") Q
   43: 	;; ;
   44: 	;; S SERVER="S.A5CSTS@FORUM.VA.GOV"
   45: 	;; S PACKAGE=$P($P(PKG,";",3),U)
   46: 	;; S SITE=$G(^XMB("NETNAME"))
   47: 	;; S START=$P($G(^DIC(9.4,VER(0),"PRE")),U,2) I '$L(START) S START="Unknown"
   48: 	;; D  ; check if ok to use kernel functions
   49: 	;; .S X="XLFDT" X ^%ZOSF("TEST") I $T D  Q
   50: 	;; ..S NOW=$$HTFM^XLFDT($H)
   51: 	;; ..S RUN="Unknown" I START S RUN=$$FMDIFF^XLFDT(NOW,START,3)
   52: 	;; ..S START=$$FMTE^XLFDT(START)
   53: 	;; ..S DATE=NOW\1
   54: 	;; ..S NOW=$$FMTE^XLFDT(NOW)
   55: 	;; .D NOW^%DTC S NOW=%,DATE=X
   56: 	;; .S RUN="" ; don't bother to compute
   57: 	;; .S Y=START D DD^%DT S START=Y
   58: 	;; .S Y=NOW D DD^%DT S NOW=Y
   59: 	;; ;
   60: 	;; ; Message for server
   61: 	;; S ^TMP("@@@@@@",$J,1,0)="PACKAGE INSTALL"
   62: 	;; S ^TMP("@@@@@@",$J,2,0)="SITE: "_SITE
   63: 	;; S ^TMP("@@@@@@",$J,3,0)="PACKAGE: "_PACKAGE
   64: 	;; S ^TMP("@@@@@@",$J,4,0)="VERSION: "_VER
   65: 	;; S ^TMP("@@@@@@",$J,5,0)="Start time: "_START
   66: 	;; S ^TMP("@@@@@@",$J,6,0)="Completion time: "_NOW
   67: 	;; S ^TMP("@@@@@@",$J,7,0)="Run time: "_RUN
   68: 	;; S ^TMP("@@@@@@",$J,8,0)="DATE: "_DATE
   69: 	;; ;
   70: 	;; ; Data is sent to server on FORUM - S.A5CSTS
   71: 	;; S XMY(SERVER)="",XMDUZ=.5,XMTEXT="^TMP(""@@@@@@"",$J,",XMSUB=PACKAGE_" VERSION "_VER_" INSTALLATION"
   72: 	;; D ^XMD
   73: 	;; K ^TMP("@@@@@@",$J)
   74: 	;; Q
   75: 	;;