Return to DINIT6.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DINIT6	;SFISC/XAK-INITIALIZE VA FILEMAN ;9/1/94  11:17
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: 	I $D(^DD("OS"))[0 D OS^DINIT
    5: 	W !!,"The following files have been installed:",!
    6: 	F X=0:0 S X=$O(^DIC(X)) Q:X>1.9999  Q:'X  W $E("   ",1,(3-$L($P(X,"."))))_X,?8,$P($G(^DIC(X,0)),U),! S ^DD(X,0,"VR")=VERSION
    7: 	S ^DD("VERSION")=VERSION,X=^DD("OS",^DD("OS"),0)
    8: 	S ^DD("SUB")=$P(X,U,3),^("ROU")=$P(X,U,4)
    9: 	D 1
   10: 	D ^DINITPST
   11: E	W !,"INITIALIZATION COMPLETED IN "_($P($H,",",2)-DIT)_" SECONDS."
   12: 	D KL Q
   13: 	;
   14: 1	N DIT
   15: 	D KL,PKG,DIINIT
   16: 	Q
   17: 	;
   18: KL	K %,%H,%X,%Y,DD,DH,DIC,DIK,DIT,DITZS,D,DA,VERSION,DU,F,I,J,P,X,Y,DIRUT,DTOUT,DUOUT
   19: 	Q
   20: PKG	;
   21: 	I $D(^DIC(9.4,0))#2,($P(^DIC(9.4,0),U,1)'="PACKAGE") D  Q
   22: 	. W !!,"You have a file #9.4 that is not the 'Package' file."
   23: 	. W !,"Therefore, the Package file will not be initialized on your system."
   24: 	. W !,"You cannot use VA FileMan's package export utility, DIFROM."
   25: 	. Q
   26: 	I $$ROUEXIST^DILIBF("XPDUTL"),$$VERSION^XPDUTL("XU")>7.1 Q
   27: 	K ^DD(9.4,913.5,2),^DD(9.4,914.5,2),^DD(9.4,916.5,2),^DD(9.44,222.7,2),^DD(9.44,222.9,2),^DD(9.44,1909)
   28: 	W !!,"Your Package file will now be updated.",!!
   29: 	D EN^DIPKINIT
   30: 	Q
   31: DIINIT	;
   32: 	I $P($G(^DIC(19,0)),U,1)="OPTION",$P($G(^DIC(19.1,0)),U,1)="SECURITY KEY" D
   33: 	. W !!,"Options and security keys will now be added to your system.",!!
   34: 	. D EN^DIINIT
   35: 	. Q
   36: 	;Put PACKAGE pointer into FM DIALOG entries, re-index file
   37: 	W !!,"Re-indexing VA FileMan entries in the DIALOG file."
   38: 	N DIPKG,DIREC S DIPKG=$O(^DIC(9.4,"C","DI",0))
   39: 	F DIREC=0:0 S DIREC=$O(^DI(.84,DIREC)) Q:'DIREC!(DIREC>10000)  D
   40: 	. S $P(^DI(.84,DIREC,0),U,4)=DIPKG
   41: 	. S DIK="^DI(.84,",DA=DIREC D IX1^DIK
   42: 	. Q
   43: 	Q