Return to DINZMGR1.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DINZMGR1	;SFISC/MKO-TO SET UP THE MGR ACCOUNT FOR THE SYSTEM ;9/8/94  13:00
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: INTRO	;Print introductory text
    5: 	W !!!,"HELLO!"
    6: 	W !!,"I exist to assist you in correctly initializing the manager account",!,"or to update the current account."
    7: 	W !!,"I'm going to do the following:"
    8: 	W !!?3,"1.  File the routines DIDT, DIDTC, and DIRCR as %DT, %DTC, and",!?7,"%RCR, respectively."
    9: 	W !!?3,"2.  File the routines DIIS and DIISS as %ZIS and %ZISS, respectively."
   10: 	W !!?3,"3.  Set nodes in the %ZOSF global.  This global contains"
   11: 	W !?7,"MUMPS operating system-specific code required by FileMan's"
   12: 	W !?7,"screen-oriented utilities."
   13: 	W !!,?3,"4.  Save a %ZOSV routine (and possibly a %ZOSV1 routine) specific",!?7,"to your MUMPS operating system."
   14: 	W !!,"Note that on some MUMPS systems, executing some of the ^%ZOSF nodes"
   15: 	W !,"causes ^XUTL global nodes to be set in the production account."
   16: 	Q
   17: 	;
   18: OS	;Prompt for operating system
   19: 	N I,J
   20: 	S Y=0
   21: 	I $D(^%ZOSF("OS"))#2 D
   22: 	. S X1=$P(^%ZOSF("OS"),U),Y=$P(^("OS"),U,2)
   23: 	. S:Y=7 X1="M\SQL",Y=18
   24: 	. I X1=""!'Y S (X1,Y)="" Q
   25: 	. W !!,"I think you are using "_X1
   26: 	. S Y=$S(Y=1:1,Y=13:2,Y=18:3,Y=2:4,Y=16:5,Y=8:6,Y=9:7,Y=17:8,1:0)
   27: 	;
   28: OS1	W !!,"Which MUMPS system are you using?",!
   29: 	F I=1:1 S J=$P($T(@I),";;",2,999) Q:J=""  D
   30: 	. W !
   31: 	. W:$P(J,";",2)]"" ?3,$P(J,";",2)
   32: 	. W ?5,I_" = "_$P(J,";")
   33: 	W !!?9,"* No longer supported."
   34: 	W !!,"MUMPS System: " W:Y Y,"// " R X:300 S:X="" X=Y
   35: 	I X[U!'$T S DIQUIT=1 Q
   36: 	;
   37: 	I X?1."?" D  G OS1
   38: 	. W !!?5,"If the MUMPS system you are using is not listed, you cannot use"
   39: 	. W !?5,"this utility.  You must manually file DIDT, DIDTC, and DIRCR as"
   40: 	. W !?5,"%DT, %DTC, and %RCR, respectively."
   41: 	. W !!?5,"In addition, if you wish to use FileMan's screen-oriented utilities,"
   42: 	. W !?5,"you must file %ZIS and %ZISS routines (you can use DIIS and DIISS"
   43: 	. W !?5,"as starting points), and you must set the %ZOSF nodes manually."
   44: 	. W !?5,"Please refer the VA FileMan Programmer Manual for more information."
   45: 	;
   46: 	S J=$P($T(@X),";;",2,999)
   47: 	I $T(@X)="" D  G OS1
   48: 	. W !!?5,$C(7)_"Invalid response.  Enter a number between 1 and 9."
   49: 	I $P(J,";",2)="*" D  G OS1
   50: 	. W !!?5,$C(7)_$P(J,";")_" is no longer supported."
   51: 	;
   52: 	S DIOS=+X
   53: 	Q
   54: 	;
   55: 1	;;M/11;*
   56: 2	;;M/SQL-PDP;*
   57: 3	;;M/SQL
   58: 4	;;DSM-4;*
   59: 5	;;DSM for OpenVMS
   60: 6	;;MSM
   61: 7	;;DTM-PC
   62: 8	;;GT.M(VAX)
   63: 9       ;;FreeM
   64: