Return to DIPKINIS.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DIPKINIS	; ; 22-DEC-1994
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: PAC(PKG,VER)	; called from package init (DIFROM7 created this routine)
    5: 	; PKG = $T(IXF) of the INIT routine.
    6: 	; VER is an array that is contained in DIFROM from the INIT routine
    7: 	;
    8: 	N %,%I,%H,DATE,DIFROM,NOW,PACKAGE,RUN,SERVER,SITE,START,X,XMDUZ,XMSUB,XMTEXT,XMY,Y K ^TMP("DIPKINIS",$J)
    9: 	;
   10: 	; Site tracking updates only occur if run in a VA production primary domain
   11: 	; account.
   12: 	I $G(^XMB("NETNAME"))'[".VA.GOV" Q
   13: 	Q:'$D(^%ZOSF("UCI"))  Q:'$D(^%ZOSF("PROD"))
   14: 	X ^%ZOSF("UCI") I Y'=^%ZOSF("PROD") Q
   15: 	;
   16: 	S SERVER="S.A5CSTS@FORUM.VA.GOV"
   17: 	S PACKAGE=$P($P(PKG,";",3),U)
   18: 	S SITE=$G(^XMB("NETNAME"))
   19: 	S START=$P($G(^DIC(9.4,VER(0),"PRE")),U,2) I '$L(START) S START="Unknown"
   20: 	D  ; check if ok to use kernel functions
   21: 	.S X="XLFDT" X ^%ZOSF("TEST") I $T D  Q
   22: 	..S NOW=$$HTFM^XLFDT($H)
   23: 	..S RUN="Unknown" I START S RUN=$$FMDIFF^XLFDT(NOW,START,3)
   24: 	..S START=$$FMTE^XLFDT(START)
   25: 	..S DATE=NOW\1
   26: 	..S NOW=$$FMTE^XLFDT(NOW)
   27: 	.D NOW^%DTC S NOW=%,DATE=X
   28: 	.S RUN="" ; don't bother to compute
   29: 	.S Y=START D DD^%DT S START=Y
   30: 	.S Y=NOW D DD^%DT S NOW=Y
   31: 	;
   32: 	; Message for server
   33: 	S ^TMP("DIPKINIS",$J,1,0)="PACKAGE INSTALL"
   34: 	S ^TMP("DIPKINIS",$J,2,0)="SITE: "_SITE
   35: 	S ^TMP("DIPKINIS",$J,3,0)="PACKAGE: "_PACKAGE
   36: 	S ^TMP("DIPKINIS",$J,4,0)="VERSION: "_VER
   37: 	S ^TMP("DIPKINIS",$J,5,0)="Start time: "_START
   38: 	S ^TMP("DIPKINIS",$J,6,0)="Completion time: "_NOW
   39: 	S ^TMP("DIPKINIS",$J,7,0)="Run time: "_RUN
   40: 	S ^TMP("DIPKINIS",$J,8,0)="DATE: "_DATE
   41: 	;
   42: 	; Data is sent to server on FORUM - S.A5CSTS
   43: 	S XMY(SERVER)="",XMDUZ=.5,XMTEXT="^TMP(""DIPKINIS"",$J,",XMSUB=PACKAGE_" VERSION "_VER_" INSTALLATION"
   44: 	D ^XMD
   45: 	K ^TMP("DIPKINIS",$J)
   46: 	Q