Return to DIPZ0.m CVS log

Up to [Coherent Logic Development] / freem_fileman / USER

Restructure repository

    1: DIPZ0	;SFISC/TKW-COMPILE PRINT TEMPLATES ;12/12/94  14:53
    2: 	;;21.0;VA FileMan;;Dec 28, 1994
    3: 	;Per VHA Directive 10-93-142, this routine should not be modified.
    4: 	;
    5: SIZ(DITYP)	;PROMPT FOR SIZE OF COMPILED ROUTINE
    6: 	;PARAMETER DITYP CONTAINS A NUMBER IN DIALOG FILE POINTING TO EITHER
    7: 	;TEXT FOR A TEMPLATE TYPE, OR TO THE TEXT 'CROSS-REFERENCES'.
    8: 	N %,DIR
    9: 	S %=$P($G(^DD("OS",DISYS,0)),U,4) S:'% %=$G(^DD("ROU")) S:'% %=5000
   10: 	S DIR(0)="N^2400:"_%_":0",DIR("B")=%,DIR("A")=$$EZBLD^DIALOG(8027)
   11: 	K % S %(1)=$$EZBLD^DIALOG(DITYP) D BLD^DIALOG(9002,.%,"","DIR(""?"")")
   12: 	D ^DIR Q
   13: 	;
   14: RNM(DITYP)	;PROMPT FOR COMPILED ROUTINE NAME
   15: 	;PARAMETER SAME AS FOR SIZ.
   16: 	N %,DIR,DIRNM
   17: 	S DIRNM="" D
   18: 	.I DITYP<8036 S DIRNM=$G(@(DIC_DIPZ_",""ROUOLD"")")),DIRNM(1)=$G(@(DIC_DIPZ_",""ROU"")"))
   19: 	.E  S DIRNM=$G(@("^DD("_DIPZ_",0,""DIKOLD"")")),DIRNM(1)=$G(@("^DD("_DIPZ_",0,""DIK"")")) S:DIRNM="" DIRNM=DIRNM(1)
   20: 	.Q
   21: 	I DIRNM(1)]"" S DIR(0)="Y",DIR("B")="NO" D  D ^DIR K DIR Q:$D(DIRUT)  I Y D UNC Q
   22: 	.K % S %(1)=$$EZBLD^DIALOG(DITYP),%(2)=DIRNM(1)
   23: 	.D BLD^DIALOG(8028,.%,"","DIR(""A"")")
   24: 	.K %(2) D BLD^DIALOG(9004,.%,"","DIR(""?"")")
   25: 	.Q
   26: 	S %=7 ;S:DITYP=8036 %=6
   27: 	S DIR(0)="F^3:"_%_"^K:X'?1U.NU&(X'?1""%""1U.NU)!(X?1""DI"".E) X" S:DIRNM]"" DIR("B")=DIRNM
   28: 	D BLD^DIALOG(8001,"","","DIR(""A"")"),BLD^DIALOG(9006,%,"","DIR(""?"")")
   29: 	D ^DIR K DIR Q:$D(DIRUT)!(X="")
   30: 	I $L(X)>6 D
   31: 	.N A,% D BLD^DIALOG(8031,"","","A") W $C(7),! F %=0:0 S %=$O(A(%)) Q:'%  W A(%),!
   32: 	.W ! Q
   33: 	I $$ROUEXIST^DILIBF(X) K % S %(1)=U_X D BLD^DIALOG(8016,.%,"","DIR") W $C(7),!?5,DIR K DIR
   34: 	Q
   35: UNC	;UNCOMPILE TEMPLATES/CROSS-REFS
   36: 	N %,DIR I DITYP<8036 K @(DIC_DIPZ_",""ROU"")")
   37: 	E  K @("^DD("_DIPZ_",0,""DIK"")")
   38: 	S %(1)=$$EZBLD^DIALOG(DITYP) D BLD^DIALOG(8026,.%,"","DIR(""A"")")
   39: 	W $C(7),!!,DIR("A")
   40: 	S X="" Q
   41: 	;
   42: 	;DIALOG #8001  'Routine Name'
   43: 	;       #8016  'Note that...is already in the routine directory'
   44: 	;       #8027  'Maximum routine size on this computer...'
   45: 	;       #8028  '...currently compiled under namespace...UNCOMPILE...'
   46: 	;       #8031  'WARNING!!  Since the namespace...routine...so long...'
   47: 	;       #8033  'Input template'
   48: 	;       #8034  'Print Template'
   49: 	;       #8036  'Cross-Reference(s)'
   50: 	;       #9002  'This number will be used to determine how large...'
   51: 	;       #9004  'Answer YES to UNCOMPILE the ...'
   52: 	;       #9006  'Enter a valid MUMPS routine name...'